Arm on iOS/Android devices - a tintin++ script

[MarshallDFX]

I made a very basic script that will give you an infobar for your iOS/android/chromebook device. I'm assuming you'll be using a Bluetooth keyboard. Once in game, it uses the same commands to install the infobar as the Mushclient plugin:  InstallInfobar, ManaOn and ManaOff.

Follow the instructions to install tintin++ on iOS https://tintin.mudhalla.net/install.php#iOS or Android https://tintin.mudhalla.net/install.php#Android
Then, after that, return to the home directory and download the script below by doing these steps:

• cd ~
• wget https://raw.githubusercontent.com/mdfx01/ArmageddonMUD/main/ArmMobile.tin

Then run the script by typing in the terminal:  tt++ ArmMobile.tin

Once mudding, the commands are the same as the Mushclient infobar to make it work properly.  Run:
- InstallInfobar
- ManaOn  (will turn mana on in your prompt)
- ManaOff (Default, will turn mana off in your prompt)

To quit out of tintin++, use #end

The script itself is very basic, there are only two highlights for stuff in the prompt.  Lots of customisation can be done.

Edit to note: currently you cannot scroll the buffer by touch, because it scrolls the terminal instead, this means you'll need to use your keyboard (eg page up page down). Tintin usés Emacs keybindings if you want to get fancy.

For reference, the script below:

Code Select Expand

#CONFIG {COLOR MODE} {256}
#CONFIG {CHARSET}  {UTF-8};
#CONFIG {COLOR PATCH}  {OFF}
#CONFIG {COMMAND COLOR}  {<g08>}
#CONFIG {COMMAND ECHO}  {ON}
#CONFIG {PACKET PATCH}  {0.5}
#CONFIG {REPEAT CHAR}  {!}
#CONFIG {REPEAT ENTER}  {OFF}
#CONFIG {SCROLL LOCK}  {ON}
#CONFIG {SPEEDWALK}  {ON}

#highlight {[armed]} {<ffe>}
#highlight {[sneaking]} {<ffe>}

#ALIAS {InstallInfobar} {
#NOP PROMPT_time_day_hunger_thirst_drunk_mood_LINEONE;
#NOP PROMPT_hp_maxhp_stamina_maxstamina_stun_maxstun_focus_maxfocus_mana_maxmana_armed_position_encumbrance_LINETWO;
#NOP PROMPT_speed_riding_accent_language_scan_listen_LINETHREE;
#send {prompt PROMPT_%e_%d_%u_%U_%R_%O_LINEONE\\nPROMPT_%h_%H_%v_%V_%t_%T_%x_%X_%m_%M_%A_%s_%E_LINETWO\\nPROMPT_%w_%k_%a_%o_%p_%P_LINETHREE\\n}
}

#ACTION {PROMPT_%1_%2_%3_%4_%5_%6_LINEONE} {
#showme {- [%1 on %2] [%3] [%4] [%5] Mood: %6 - } {1}
} {1}

#ACTION {PROMPT_%1_%2_%3_%4_%5_%6_%7_%8_%9_%10_%11_%12_%13_LINETWO} {
   #if {"$Mana" == "Off"} {#showme {- hp:%1/%2 mv:%3/%4 st:%5/%6 fs:%7/%8 [%11] [%12] [%13] -} {-6}}; #else {
   #showme {- hp:%1/%2 mv:%3/%4 st:%5/%6 fs:%7/%8 mn:%9/%10 [%11] [%12] [%13] -} {-6}}
} {1}

#ACTION {PROMPT_%1_%2_%3_%4_%5_%6_LINETHREE} {
  #showme {- [%1] [%2] [%3 %4] [%5 %6] -} {-5}
} {1}

#GAG {PROMPT_%*_LINEONE}
#GAG {PROMPT_%*_LINETWO}
#GAG {PROMPT_%*_LINETHREE}

#var Mana Off
#alias ManaOn {#var Mana On; #showme Displaying mana values}
#alias ManaOff {#var Mana Off; #showme Hiding mana values}

#split 2 4 0 0 3

#session Armageddon ginka.armageddon.org 4050